AT89C2051的一個特殊應(yīng)用，用它的比較器做一個光強調(diào)節(jié)器，應(yīng)用在全靜態(tài)LED顯示屏上。當(dāng)初的情況是原有LED 顯示屏的光控是用專用的AD轉(zhuǎn)換芯片做的，比較貴。最后用這個方案做為一個補丁用了一下。

它的使用原理是：用單片機的比較器和電容及光敏電阻組成一個充放電電路，用單片機的兩個定時器組成一個PWM信號輸出。PWM信號從一個端口輸出，然后控制LED 顯示屏的顯示使能信號，這樣就可以做到在夜間LED顯示屏變暗一點，的天變亮一點。以達(dá)到一個最好的效果。

ORG 0000H
LJMP MAIN
ORG 000BH
LJMP TIMER0 ;改變占空比
ORG 001BH
LJMP TIMER1 ;定時10MS
ORG 0030H
MAIN: MOV SP,#70H
MOV P1,#0FFH
CLR P1.1
MOV P3,#0FFH
MOV TMOD,#11H
MOV IE,#8AH
MOV TH1,#0DCH ;定時10MS,掃描頻率100HZ
MOV TL1,#00H
MOV TH0,#00H ;根據(jù)光強改變亮度占空比
MOV TL0,#00H
MOV 30H,#00H
MOV 31H,#00H
MOV 32H,#50 ;配合定時器1完成啟動光檢測的時間500MS
;MOV 33H,#5
MOV 34H,#055H ;十秒到標(biāo)志,055H為時間到
;MOV 35H,#0AAH ;啟動比較器標(biāo)志，55H為啟動
SETB TR1
MAIN1: SETB ET0
CPL P1.4
MOV A,34H
CJNE A,#55H,MAIN1
MOV 34H,#0AAH
CLR TR0
CLR ET0
MOV TH0,#00H
MOV TL0,#00H
SETB TR0
SETB P1.1
JB P3.6,$
CLR TR0
SETB P3.7
CLR P1.1
CPL P1.5
MOV 30H,TH0
MOV 31H,TL0
MOV A,#0FFH
CLR C
SUBB A,31H
MOV 31H,A
MOV A,#0FFH
SUBB A,30H
MOV 30H,A
LJMP MAIN1


TIMER1: PUSH ACC
MOV TH1,#0DCH
MOV TL1,#00H
MOV TH0,30H
MOV TL0,31H
SETB TR0
CLR P3.7
CPL P1.7
DJNZ 32H,T1ZD1
MOV 32H,#50
MOV 34H,#55H ;500MS
T1ZD1: POP ACC
RETI

TIMER0: PUSH ACC
CLR TR0
MOV TH0,30H
MOV TL0,31H
SETB P3.7
cpl p1.6
POP ACC
RETI

END